[Arduino] DS18B20 搭配5110 LCD做輸出

我想把溫度顯示在5110 LCD上，請參考以下二篇文章

[Arduino]DS18B20 防水溫度計

[Arduino] LCD5110


接線下方式如下

5110 LCD                 Arduino        

LCD                          D2  

SCLK                        D3

DIN<MOSI>           D4

D/C                         D5

RST                           D6

SCE                         D7

GDN                       GND

VCC                       5V               

------------------------------------
DS18B20            Arduino

Red                        5V

Black                    GND

Yellow                 D10

#include <OneWire.h>

#include <PCD8544.h>

OneWire  ds(10);  // on pin 10 (a 4.7K resistor is necessary)
// A custom glyph (a smiley)...

// A custom "degrees" symbol...
static const byte DEGREES_CHAR = 1;
static const byte degrees_glyph[] = { 0x00, 0x07, 0x05, 0x07, 0x00 };
int lcd_bg= 2;
static PCD8544 lcd;
void setup() {
  // put your setup code here, to run once:
  Serial.begin(9600);
 // PCD8544-compatible displays may have a different resolution...
  lcd.begin(84, 48);
  
   // Register the custom symbol...
  lcd.createChar(DEGREES_CHAR, degrees_glyph);
}

void loop() {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
  pinMode(lcd_bg,OUTPUT);
  digitalWrite(lcd_bg,HIGH);
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
 
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
  
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
  
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
  lcd.setCursor(0, 0);
  //lcd.print("Software Lab"); 
  lcd.print("Living Room"); 
  lcd.setCursor(0, 2);
  lcd.print("Aquarium Temp:");
  lcd.setCursor(0,4);
  lcd.print(celsius,1);
  lcd.print(" \001C ");
}

比較要注意的是這二行

static const byte DEGREES_CHAR = 1;
static const byte degrees_glyph[] = { 0x00, 0x07, 0x05, 0x07, 0x00 };

這是用來繪制度西的"度"，如果你把DEGREES_CHAR改成別的值

lcd.print(" \001C ");也要把\001改成相對應的值

執行結果